• Биполярные транзисторы
  • Выходные характеристики
  • Входные характеристики
  • Усилители с общим эмиттером
  • Анализ цепей смещения
  • Анализ на переменном токе
  • Усилитель с общим эмиттером с нешунтированным эмиттерным резистором
  • Определение входного сопротивления
  • Применение собственных моделей с h-параметрами
  • Анализ с помощью h-параметров
  • Фазовые соотношения в усилителе с общим эмиттером
  • Усилитель без эмиттерного конденсатора
  • Усилитель с эмиттерным конденсатором
  • Триггер на биполярных транзисторах
  • Анализ на PSpice
  • Симметричный мультивибратор
  • Мультивибратор с эмиттерными связями на биполярных транзисторах
  • Задачи
  • 10. Биполярные транзисторы и их модели 

    Биполярные транзисторы

    Эта глава знакомит читателя с использованием библиотечной модели биполярного транзистора (BJT), которая сравнивается с использованными ранее моделями в h-параметрах или с другими упрощенными моделями. В PSpice встроена универсальная модель для BJT, в которой используются параметры, приведенные в разделе «Q — биполярный транзистор» приложения D. Полезно рассмотреть как входную, так и выходную характеристики этой модели. Это позволит нам при необходимости использовать эту модель в различных схемах.

    Выходные характеристики

    Схема для получения выходных характеристик (рис. 10.1) содержит источник постоянного напряжения VCC с варьируемым выходным напряжением и источник постоянного тока IВ с варьируемым током. Транзистор обозначен как Q1. При использовании встроенной модели BJT обозначение прибора всегда должно начинаться с символа Q. Входной файл при этом имеет вид:

    BJT Output Characteristics

    VCC 4 0 10V

    IB 0 1 2 5uA

    RB 1 2 0.01

    RC 4 3 0.01

    Q1 3 2 0 BJT; the designation BJT is our choice

    .MODEL BJT NPN (BF-80)

    .dc VCC 0 10V 0.05V 1B 5uA 2 5uA 5uA

    .PROBE

    .END

    Рис. 10.1. Схема для снятия выходных характеристик биполярного транзистора


    Команда .MODEL показывает, что выбраны имя BJT для модели и тип NPN для транзистора. Значение по умолчанию для прямого коэффициента передачи BF (hFE) равно 100, но оно изменено на 80 последней записью команды. Подобным образом можно изменить и другие параметры модели, иначе будут использоваться значения, задаваемые по умолчанию. Команда .dc содержит внешний цикл для вариации VCC и внутренний цикл вариации IВ

    Внимание: Если вы попытаетесь задать значение IВ=0 мкА, вариация по постоянному току (dc sweep) будет выполнена некорректно.

    Проведите анализ и получите в Probe график I(RC). Этот график приведен на рис. 10.2. Полезно маркировать различные характеристики соответствующими значениями входного тока. Диапазон по оси Y был изменен, границы его установлены от 0 до 2,1 мА.

    Рис. 10.2. Выходные характеристики биполярного транзистора


    Обратите внимание, что при IВ=25 мкА и VCC (фактически VCE) выражается в долях вольта, а ток коллектора, показанный на графике как I(RC), равен 2,0 мА, что соответствует значению hFE=80. 

    Входные характеристики

    Чтобы получить входные характеристики, можно использовать схему, показанную на рис. 10.3. Источник тока IВВ превращается в неидеальный при включении параллельно его выходу резистора Rs. Входной файл:

    BJT Input Characteristics

    IBB 0 1 100uA

    Rs 1 0 1000k

    RL 2 3 0.01

    Q1 2 1 0 BJT

    VCC 3 0 10V

    .MODEL BJT NPN(BF=80)

    .dc IBB 0 100uA 1uA VCC 0V 10V 2V

    .PROBE

    .END

    Рис. 10.3. Схема для снятия входных характеристик биполярного транзистора


    После проведения анализа измените разметку оси X чтобы показать и V(1), и график тока I(IBB). Вы получите график, который показывает только две кривые. Первая, расположенная ближе к началу координат, получена для VCE=0 В, другая — для всех остальных значений VCE (см. рис. 10.4). Если выполнить анализ, исключив нулевое значение VCC, то первая кривая на графике исчезнет. Обратите внимание, что при использовании встроенной модели для Q напряжение VBE будет приблизительно равно 0,8 В для типичных значений базового тока.

    Рис. 10.4 Входные характеристики биполярного транзистора

    Усилители с общим эмиттером

    Простая схема каскада с ОЭ показана на рис. 10.5. Входной контур получен путем преобразования более сложной цепи с помощью теоремы Тевенина. Мы проводим анализ при частоте 5 кГц, при которой конденсаторы могут рассматриваться просто как короткое замыкание, поэтому конденсатор связи в схеме отсутствует. Зададим значение hFE=50. Входной файл:

    Рис. 10.5. Усилитель ОЭ на биполярном транзисторе 


    СЕ Amplifier, BJT Model

    VCC 5 0 18V

    VBB 3 2 0.8V

    RS 1 2 1k

    RL 4 5 10k

    Q1 4 3 0 BJT

    .MODEL BJT NPN(BF=50)

    .TF V(4) VS .OP

    .OPT nopage

    vs 1 0 ac 1mV

    .AC lin 1 5kHz 5kHz

    .PRINT ас I(RS) I(RL) V(3) V(4)

    .END

    В команде .АС задана частота 5 кГц. Команда .PRINT ас позволяет нам находить определенные токи и напряжения. Выходной файл PSpice анализа показан на рис. 10.6. Различные формулы могли бы использоваться, чтобы вычислить коэффициент усиления по напряжению V(4)/V(3), например,

    если использовать принятое значение hie=1,1 кОм. Затем при использовании отношения для делителя напряжений между RL и hie можно определить коэффициент усиления по напряжению V(4)/VS=-238. В выходном файле, полученном на PSpice согласно малосигнальным характеристикам, показано значение V(4)/VS, равное -233, что достаточно близко к вычисленному значению. Входное сопротивление относительно VS, также выведенное в выходном файле, равно 2,144 кОм. Вычитая из него внутреннее сопротивление источника Rs (1 кОм), получим hie=1,144 кОм, что также близко к принятому значению. Выходное сопротивление составляет 10 кОм. В практических случаях схема замещения выходного сопротивления представляет собой параллельное соединение RL и hoe. Но если мы примем, что hoe>RL, то выходное сопротивление будет близко к RL. Обратите внимание, что при включении во входную цепь конденсатора этот метод нахождения малосигнальных характеристик не даст полезных результатов.

    СЕ Amplifier, BJT Model

    VCC 5 0 18V

    VBB 3 2 0.8V

    RS 1 2 1K

    RL 4 5 10k

    Q1 4 3 0 BJT

    .MODEL BJT NPN(F=50)

    .TF V(4) VS

    .OP

    .OPT nopage

    vs 1 0 ac 1mV

    .AC lin 1 5kHz 5kHz

    .PRINT ac I(RS) I(RL) V(3) V(4)

    .END

    **** BJT MODEL PARAMETERS

       BJT

       NPN

    IS 100.000000E-18

    BF 50

    NF 1

    BR 1

    NR 1

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) 0.0000  ( 2) -.0226  ( 3) .7774   ( 4) 6.6929

    ( 5) 18.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.131E-03

    VBB -2.261E-05

    VS  -2.261E-05

    TOTAL POWER DISSIPATION 2.04E-02 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME   Q1

    MODEL  BJT

    IB     2.26E-05

    IС     1.13E-03

    VBE    7.77E-01

    VBC   -5.92E+00

    VCE    6.69E+00

    BETADC 5.00E+01

    BETAAC 5.00E+01

    **** SMALL-SIGNAL CHARACTERISTICS

    V(4)/VS = -2.332E+02

    INPUT RESISTANCE AT VS = 2.144Е+03

    OUTPUT RESISTANCE AT V(4) = 1.000E+04

    **** AC ANALYSIS TEMPERATURE = 27.000 DEG С

    FREQ      I(RS)     I(RL)     V(3)      V(4)

    5.000E+03 4.665E-07 2.332E-05 5.335E-04 2.332E-01

    Рис. 10.6. Выходной файл с результатами анализа схемы на рис. 10.5


    Последние строки выходного файла содержат результаты анализа на переменном токе. Частота составляет 5 кГц, ток базы равен 0,46665 мкА, а ток коллектора составляет 23,32 мкА. Чтобы проверить эти значения с помощью стандартного схемотехнического анализа мы должны найти переменную составляющую тока базы. Она равна

    Переменная составляющая тока коллектора

    Ic = hfeIb = 50 (0,476 мкА) = 23,37 мкА.

    Эти значения близки к результатам, полученным в PSpice.

    Возвратимся к анализу на постоянном токе и вычислим постоянную составляющую тока базы:

    Это предварительное значение, так как VBE получено из результатов PSpice. Теперь становится очевидно, что эта схема применима скорее для иллюстрации, чем для практических целей, так как даже незначительные изменения VBB или VBE вызовут большие изменения в IВ. Вычислим теперь постоянную составляющую тока коллектора, найденную как hfeIb, что даст нам значение 1,13 мА и напряжение коллектора

    VC = VCC – RLIC = 18 В – (10 кОм) (1,13 мА) = 6,7 В.

    Общая рассеиваемая мощность, показанная в PSpice как произведение тока на напряжение источника питания, равна 20,4 мВт. 

    На рис. 10.6 приведена распечатка выходного файла нашего анализа на PSpice. Для выбранного нами транзистора с именем Q1 и модели с именем BJT в выходном файле приведен список из 16 параметров (на рис. 10.6 показана лишь часть из них). Эти значения справедливы для конкретных условий смещения схемы. Они изменятся при изменении токов и напряжений покоя. Например, если транзистор войдет в режим насыщения, значение BETADC будет намного ниже. После изучения результатов обратимся к практической схеме и проведем расширенный анализ.

    Анализ цепей смещения

    Схема с более устойчивой точкой покоя, чем в предыдущем случае, показана на рис. 10.7. Она называется схемой с эмиттерным или автоматическим смещением. Входной файл:

    Biasing Case Study

    VCC 2 0 12V

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 220

    Q1 3 1 4 Q2N2222

    .LIB EVAL.LIB; команда вызывает библиотечный файл EVAL.LIB

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC) I(R1) I(R2) I(RE)

    .OP

    .OPT nopage

    .END

    Рис. 10.7. Схема с цепями смещения


    В этом входном файле отсутствует команда .MODEL. Вместо этого транзистор определяется как Q2N2222 (npn). Это — обозначение для одного из транзисторов, который смоделирован в рабочей версии PSpice.

    Другими библиотечными типами транзисторов BJT, приведенными в приложении Е, являются Q2N2907A (pnp), Q2N3904 (npn), Q2N3906 (pnp). Чтобы использовать ресурсы библиотеки, входной файл должен включать строку, начинающуюся с .LIB. Промышленная версия PSpice содержит намного больше транзисторов, чем перечислено здесь. Библиотека находится в файле, названном eval.lib. Найдите листинг .model Q2N2222 в приложении Е, который начинается со строк

    .model QN2222 NPN(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9....)

    В этой команде задаются различные параметры модели. Так, величина Is представляет собой ток насыщения pn-перехода и т.д. Полная распечатка параметров BJT дана в приложении D (раздел «Q — биполярный транзистор»). Проведите моделирование и проверьте напряжения и токи в рабочей точке. Убедитесь, что VCE=6,5185 В и что ток коллектора IС=1,114 мА. Обратите внимание на то, что, хотя Q1 имеет максимальный прямой коэффициент передачи hFE=255,9, в информации о рабочей точке задано значение BETADC, равное 160 при токе базы IВ=6,96 мА. Выходной файл приведен на рис. 10.8 (показаны не все параметры модели).

    Biasing Case Study

    VCC 2 0 12V

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 220

    Q1 3 1 4 Q2N2222

    .LIB EVAL.LIB ; this calls in the library file EVAL.LIB

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC) I(R1) I(R2) I(RE)

    .OP

    .OPT nopage .END

    **** BJT MODEL PARAMETERS

       Q2N2222

       NPN

    IS 14.340000E-15

    BF 255.9

    NF 1

    VAF 74.03

    **** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG С

    VCC       I(RC)     I(R1)     I(R2)     I(RE)

    1.200E+01 1.114E-03 2.777E-04 2.707E-04 1.121E-03

    **** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) .8933  ( 2)  12.0000 ( 3) 6.7651  ( 4) .2466

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.391E-03

    TOTAL POWER DISSIPATION 1.67E-02 WATTS

    OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME     Q1

    MODEL    Q2N2222

    IB       6.96E-06

    IС       1.11E-03

    VBE      6.47E-01

    VBC     -5.87E+00

    VCE      6.52E+00

    BETADC   1.60E+02

    GM       4.29E-02

    RPI      4.12E+03

    RX       1.00E+01

    RO       7.17E+04

    CBE      5.40E-11

    CBC      3.47E-12

    CJS      0.00E+00

    BETAAC   1.77Е+02

    CBX/CBX2 0.00E+00

    FT/FT2   1.19E+08

    Рис. 10.8. Выходной файл с результатами анализа схемы на рис. 10.7

    Анализ на переменном токе

    Чтобы показать, как ведет себя эта схема в качестве усилителя ОЭ, добавим несколько компонентов (рис. 10.9). Максимальное значение переменного напряжения равно 10 мВ, внутреннее сопротивление источника Rs=50 Ом, кроме того добавлены конденсаторы Сb и Се. Входной файл принимает вид:

    Biasing Case Study Extended

    VCC 2 0 12V

    Vs 1a 0 ac 10mV

    Rs 1a 1b 50

    Cb 1b 1 15uF

    Ce 4 0 15uF

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 22 0

    Q1 3 1 4 Q2N2222

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC) I(R1) I(R2) I(RE)

    .OP

    .opt nopage nomod; подавляется вывод баннера и параметров модели

    .ас LIN 1 5kHz 5kHz; задается вариация для анализа на переменном токе

    .PRINT ас i(RC) i(RE) i(RS)

    .PRINT ac v(1) v(1b) v(3) v(4)

    .LIB EVAL.LIB

    .END

    Рис. 10.9. Усилитель ОЭ


    В этом входном файле величина Vs идентифицируется как переменная составляющая входного напряжения, и вызывается вариация по переменному току (ас sweep). Без команды .ас LIN выходной файл вообще не будет содержать информации о переменных составляющих.

    Проведите анализ и убедитесь, что напряжение смещения и значения токов не изменились по сравнению с предыдущим выходным файлом. Фактически вся информация о рабочей точке осталась прежней. Выходной файл приведен на рис. 10.10. 

    Biasing Case Study Extended

    VCC 2 0 12V

    Vs 1a 0 ас 10mV

    Rs 1a 1b 50

    Cb 1b 1 15uF

    Ce 4 0 15uF

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 220

    Q1 3 1 4 Q2N2222

    .DC VCC 12V 122V 212V

    .PRINT DC I(RC) I(R1) I(R2) I(RE)

    .OP

    .opt nopage nomod ; suppress banner and model parameters

    .ac LIN 1 5kHz 5kHz ; a sweep is necessary for ac analysis

    .PRINT ac i(RC) i(RE) I(RS)

    .PRINT ac v(1) v(1b) v(3) v(4)

    .LIB EVAL.LIB

    .END

    **** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG С

    VCC       I(RC)     I(R1)     I(R2)     I(RE)

    1.200E+01 1.114Е-03 2.777E-04 2.707E-04 1.121E-03

    **** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

    NODE  VOLTAGE NODE  VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1)  .8933   ( 2)  12.0000 ( 3) 6.7651  ( 4) .2466

    ( 1a) 0.0000  ( 1b) 0.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.391E-03

    Vs   0.000E+00

    TOTAL POWER DISSIPATION 1.67E-02 WATTS

    **** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME   Q1

    MODEL  Q2N2222

    IB     6.96E-06

    IС     1.11E-03

    VBE    6.47E-01

    VBC   -5.87E+00

    VCE    6.52E+00

    BETADC 1.60E+02

    BETAAC 1.77E+02

    **** AC ANALYSIS TEMPERATURE = 27.000 DEG С

    FREQ       I(RC)     I(RE)     I(RS)

    5.000E4-03 3.888E-04 3.772E-06 5.523E-06

    FREQ      V(1)      V(1b)     V(3)      V(4)

    5.000E+03 9.724E-03 9.725E-03 1.827E+00 8.299E-04

    Рис. 10.10. Выходной файл с результатами анализа схемы на рис. 10.9


    В дополнение к предыдущим результатам мы запросили сведения о переменных составляющих нескольких токов и напряжений. Убедитесь, что v(3)/v(1)=188 и v(3)/vs=182,7. Переменная составляющая выходного тока составляет 0,3888 мА, переменная составляющая входного тока равна 5,523 мкА, что дает для коэффициента усиления по току значение 70,4.

    В качестве упражнения включите резистор с сопротивлением RB=0,01 Ом последовательно с базой и выведите значение тока через RB с помощью команды .PRINT ас; затем выполните анализ и найдите коэффициент передачи по току с базы на коллектор. Он не будет таким же, как найденный с использованием Ic/hfe, где hfe — это ВЕТААС. Можете ли вы дать объяснение этому?

    Для понимания работы схемы полезно рассмотреть переменные составляющие напряжений в различных точках схемы. Измените входной файл следующим образом:

    Biasing Case Study Extended for Probe

    VCC 2 0 12V

    Vs 1a 0 sin(0 10mV 5kHz)

    ;аргументы - смещение, максимальное значение и частота

    Rs 1a 1b 50

    Cb 1b 1 15uF

    Ce 4 0 15uF

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 220

    Q1 3 1 4 Q2N2222

    .opt nopage nomod

    .TRAN 0.02ms 0.6ms

    .PROBE

    .FOUR 5kHz V(3)

    .LIB EVAL.LIB

    .END

    Источник напряжения показан теперь не просто как источник переменного, а как источник именно синусоидального напряжения sin(). Параметрами его являются смещение, амплитуда и частота. Временные диаграммы можно получить путем включения во входной файл команды .PROBE. Проведите анализ, затем получите графики v(3) и v(1), показанные на рис. 10.11. На этом рисунке использовался курсор, чтобы найти максимальное значение напряжения коллектора. Обратите внимание, что напряжение коллектора повернуто на 180° относительно напряжения базы. Используйте курсор, чтобы найти максимум и минимум.

    Рис. 10.11. Временные диаграммы напряжений на коллекторе и на базе в схеме на рис. 10.9


    Убедитесь, что размах напряжения на базе (удвоенная амплитуда) равен 19,4 мВ, в то время как соответствующее значение на коллекторе равно 3,62 В что дает коэффициент усиления по напряжению Av=187, соответствующий результату предыдущего анализа на переменном токе.

    Последние строки выходного файла, показанного на рис 10.12, содержат результаты гармонического анализа выходного напряжения V(3). Постоянная составляющая, равная 6,75 В, в точности совпадает с напряжением смещения на коллекторе. Амплитуда основной гармоники (5 кГц) равна 1,781 В, что соответствует размаху в 3,562 В. График коллекторного напряжения дает размах 3,63 В. Вторая гармоника выходного напряжения составляет 0,134 В, что на порядок меньше основной. Более высокие гармоники имеют еще меньшую величину и дают общее гармоническое искажение приблизительно в 7,5%.

    Biasing Case Study Extended for Probe

    VCC 2 0 12V

    Vs 1a 0 sin(0 10mV 5kHz) ; arguments are offset, peak, and frequency

    Rs 1a 1b 50

    Cb 1b 1 15uF

    Ce 4 0 15uF

    R1 2 1 40k

    R2 1 0 3.3k

    RC 2 3 4.7k

    RE 4 0 220

    Q1 3 1 4 Q2N2222

    .opt nopage nomod

    .TRAN 0.02ms 0.6ms

    .PROBE

    .FOUR 5kHz V(3)

    .LIB EVAL.LIB

    .END

    **** INITIAL TRANSIENT SOLUTION TEMPERATURE = 27.000 DEG С

    NODE  VOLTAGE NODE  VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1)  .8933   ( 2)  12.0000 ( 3) 6.7651  ( 4) .2466

    ( 1a) 0.0000  ( 1b) 0.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.391E-03

    Vs   0.000E+00

    TOTAL POWER DISSIPATION 1.67E-02 WATTS

    **** FOURIER ANALYSIS TEMPERATURE -27.000 DEG С

    FOURIER COMPONENTS OF TRANSIENT RESPONSE V(3)

    DC COMPONENT = 6.757350Е+00

    HARMONIC FREQUENCY FOURIER   NORMALIZED PHASE     NORMALIZED

    NO       (HZ)      COMPONENT COMPONENT (DEG)      PHASE (DEG)

    1        5.000E+03 1.780E+00 1.000E+00 -1.752E+02 0.000E+00

    2        1.000E+04 1.343E-01 7.541E-02  1.019E+02 2.771E+02

    3        1.500E+04 4.445E-03 2.496E-03 -1.089E+01 1.643E+02

    4        2.000E+04 2.902E-03 1.630E-03 -1.114Е+02 6.384E+01

    5        2.500E+04 2.710E-03 1.522E-03 -1.204E+02 5.485E+01

    6        3.000E+04 2.695E-03 1.514E-03 -1.277B+02 4.750B+01

    7        3.500E+04 2.638E-03 1.482E-03 -1.337E+02 4.154Е+01

    8        4.000E+04 2.563E-03 1.440E-03 -1.402E+02 3.502E+01

    9        4.500E+04 2.430Е-03 1.3651-03 -1.442E+02 3.100Е+01

    TOTAL HARMONIC DISTORTION = 7.553840E+00 PERCENT

    Рис. 10.12. Выходной файл с результатами анализа Фурье для схемы на рис. 10.9

    Усилитель с общим эмиттером с нешунтированным эмиттерным резистором

    Когда усилитель ОЭ использует эмиттерный резистор, не шунтированный конденсатором, коэффициент усиления по напряжению схемы уменьшается, зато улучшается частотная характеристика. Схема с последовательной обратной связью по току показана на рис. 10.13. Используем для анализа встроенную модель BJT при hFE= 80. Входной файл при этом:

    Analysis of СЕ Amplifier with Unbypassed RE

    VCC 4 0 12V

    R1 4 1 40k

    R2 1 0 5k

    RC 4 2 1k

    RE 3 0 100

    Rs 6 5 100

    Rb 1 1a 0.01

    C1 5 1 15uF

    Q1 2 1a 3 BJT

    .MODEL BJT NPN (BF=80)

    .OP

    .OPT nopage

    vs 6 0 ас 10mV

    .ас LIN 1 5kHz 5kHz

    .PRINT ac i(RB) i(RC) i(RS) v(1) v(2) v(3)

    .END

    Рис. 10.13. Усилитель ОЭ с нешунтированным эмиттерным сопротивлением


    Анализ на постоянном токе для этой схемы был приведен в разделе «Краткий обзор PSpice» в начале книги и мы не будем повторять его здесь.

    Проведем расчет для переменных составляющих с использованием стандартного схемотехнического анализа. Коэффициент передачи по напряжению (с базы на коллектор) можно аппроксимировать выражением

    но для малых значении это выражение может давать относительную ошибку в 10%. Более точное уравнение:

    Поскольку это коэффициент передачи по напряжению с базы на коллектор, необходимо использовать формулу для делителя напряжения, чтобы найти коэффициент передачи по напряжению с источника на коллектор:

    где Rp — эквивалентное сопротивление для параллельного соединения R1, R2 и Ri.

    Обратимся теперь к выходному файлу (рис. 10.14), чтобы посмотреть, насколько анализ на PSpice сопоставим с результатами обычного расчета. PSpice дает для полного коэффициента передачи по напряжению V(2)/vs = -8,878, что отличается от расчетного значения немногим более, чем на 5%.

    Analysis of СЕ Amplifier with Unbypassed RE

    VCC 4 0 12V

    R1 4 1 40k

    R2 1 0 5k

    RC 4 2 1k

    RE 3 0 100

    Rs 6 5 100

    Rb 1 1a 0.01

    C1 5 1 15uF

    Q1 2 1a 3 BJT

    .MODEL BJT NPN (BF=80)

    .OP

    .opt nopage

    vs 6 0 ac 10mV

    .ас LIN 1 5kHz 5kHz

    .PRINT ac i(RB) i(RC) i(RS) v(1) v(2) v(3) .END

    NODE VOLTAGE NODE VOLTAGE NODE  VOLTAGE NODE VOLTAGE

    ( 1) 1.1464  ( 2) 8.6345  ( 3)  .3408  ( 4)  12.0000

    ( 5) 0.0000  ( 6) 0.0000  ( 1a) 1.1464

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -3.637E-03

    vs   0.000E+00

    TOTAL POWER DISSIPATION 4.36E-02 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME     Q1

    MODEL    BJT

    IB       4.21E-05

    IС       3.37E-03

    VBE      8.06E-01

    VBC     -7.49E+00

    VCE      8.29E+00

    BETADC   8.00E+01

    GM       1.30Е-01

    RPI      6.15E+02

    RX       0.00E+00

    RO       1.00E+12

    CBE      0.00E+00

    CBC      0.00E+00

    CJS      0.00E+00

    BETAAC   8.00E+01

    CBX/CBX2 0.00E+00

    FT/FT2   2.07E+18

    **** AC ANALYSIS TEMPERATURE = 27.000 DEG С

    FREQ      I(RB)     I(RC)     I(RS)     V(1)      V(2)

    5.000E+03 1.110E-06 8.878E-05 3.286E-06 9.671E-03 8.878E-02

    FREQ      V(3)

    5.000E+03 8.989E-03

    Рис. 10.14. Выходной файл с результатами анализа схемы на рис. 10.13

    Определение входного сопротивления

    Желательно, кроме того, найти входное сопротивление со стороны источника входного напряжения. Если мы просто используем команду

    .TF V(4) vs

    результаты будут некорректными. Вы можете это сделать и посмотреть, что получится. Удаление конденсатора С1 из схемы также не сработает, так как это приведет к изменению условий смещения.

    Правильный подход показан на рис. 10.15, где во входную цепь включен источник с напряжением и внутренним сопротивлением, определенными по теореме Тевенина. При этом поддерживаются соответствующие напряжения и токи смещения, и можно использовать функцию преобразования .TF.

    Рис. 10.15. Схема для определения входного сопротивления усилителя ОЭ


    Из выходного файла на рис. 10.16 (содержащего также листинг входного файла) можно видеть, что напряжения смещения не изменились. Эта распечатка показывает входное сопротивление как 13,16 Ом. Сопротивление в цепи базы транзистора Ri=13,16–4,444=8,7 кОм. Расчетное значение 9,2 кОм отличается от этого немногим больше, чем на 5%, из чего мы заключаем, что оба метода адекватны.

    Find Input Resistance of CE Amplifier Circuit with RE

    VCC 4 0 12V

    VTh 1 1a 1.33333V

    RC 4 2 1k

    RE 3 0 100

    Rs 5 1a 4.4444k

    Q1 2 1 3 BJT

    .MODEL BJT NPH(BF=80)

    .TF v(2) vs

    .OP

    .opt nopage

    vs 5 0 ac 10mV

    .ac LIN 1 5kHz 5kHz

    .PRINT ac i(Rs) i(RC) v(1) v(2) v(3)

    . END

    NODE VOLTAGE NODE  VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) 1.1464  ( 2)  8.6345  ( 3) .3408   ( 4) 12.0000

    ( 5) 0.0000  ( 1a) -.1870

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -3.366E-03

    VTh -4.207E-05

    vs  -4.207E-05

    TOTAL POWER DISSIPATION 4.04E-02 WATTS

    **** SMALL-SIGNAL CHARACTERISTICS

    V(2)/vs = -6.079Е+00

    INPUT RESISTANCE AT vs. = 1.316E+04

    OUTPUT RESISTANCE AT V(2) = 1.000E+03

    FREQ      I(Rs)     I(RC)     V(1)      V(2)      V(3)

    5.000E+03 7.599E-07 6.079E-05 6.623E-03 6.0791-02 6.155E-03

    Рис. 10.16. Выходной файл с результатами анализа схемы на рис. 10.15

    Применение собственных моделей с h-параметрами

    Сравним теперь нахождение коэффициентов усиления по напряжению и по току двумя методами: при использовании встроенной модели PSpice и при применении нашей собственной модели в h-параметрах для усилителя ОЭ. Последний метод представлен в главе 3.

    Анализ с помощью h-параметров

    Схема на рис. 10.13 рассматривается относительно переменных составляющих. Узел источника VCC заземляется (при этом R1 подсоединяется параллельно R2), конденсатор С1 закорачивается. Преобразованная таким образом схема показана на рис. 10.17, а при использовании вместо транзистора модели в h-параметрах она приобретает вид, показанный на рис. 10.18.

    Рис. 10.17. Схема усилителя с ОЭ для анализа переменных составляющих


    Рис. 10.18. Схема на рис. 10.17 с моделью транзистора в h-параметрах


    Вспомним, что значительно больше информации может быть получено, если мы будем проводить анализ на постоянном, а не на переменном токе. Это позволяет нам находить необходимые характеристики для малого сигнала, включая коэффициент усиления по напряжению и входное сопротивление. Мы не будем приводить здесь входной файл, поскольку он показан в распечатке выходного файла на рис. 10.19. Результаты анализа близки к полученным ранее с использованием встроенной модели BJT.

    CE Amplifier with Re using h-parameter model

    vs 1 0 10mV

    VO 3 2A 0

    E 3A 4 5 4 2.5E-4

    F 5 4 VO 80

    Rs 1 2 100

    R1 2 0 40k

    R2 2 0 5k

    RI 2 3 1.1k

    RO 5 4 40k

    RC 0 5 1k

    RE 4 0 100

    .TF V(5) Vs

    .OP

    .opt nopage

    .dc ve 10mV 10mV 10mV

    .PRINT dc i(RC) i(Rs) i(RI) i(RE)

    .END

    vs        I(RC)     I(Rs)     I(RE)     I(RE)

    1.000E-02 8.402E-05 3.256E-06 1.079E-06 8.510E-05

    NODE VOLTAGE NODE  VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) .0100   ( 2)  .0097   ( 3) .0085   ( 4) .0005

    ( 5) -.0840  ( 3A) .0085

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    vs  -3.256E-06

    VO   1.079E-06

    TOTAL POWER DISSIPATION 3.26E-08 WATTS

    **** VOLTAGE-CONTROLLED VOLTAGE SOURCES

    NAME      E

    V-SOURCE -2.313E-05

    I-SOURCE -1.079E-06

    **** CURRENT-CONTROLLED CURRENT SOURCES

    NAME F

    I-SOURCE 8.634E-05

    **** SMALL-SIGNAL CHARACTERISTICS

    V(5)/vs = -8.402E+00

    INPUT RESISTANCE AT vs = 3.071E+03

    OUTPUT RESISTANCE AT V(5) = 9.987Е+02

    Рис. 10.19. Выходной файл с результатами анализа схемы на рис. 10.18

    Фазовые соотношения в усилителе с общим эмиттером

    Когда в усилителе с ОЭ для стабилизации параметров смещения используется эмиттерный резистор RЕ, он шунтируется конденсатором СЕ с такой емкостью, чтобы на частоте входного сигнала эмиттер можно было бы считать заземленным. Если мы рассматриваем временные диаграммы для переменных составляющих токов в коллекторе и эмиттере, то интересно сравнить, каким будет коэффициент усиления с применением и без применения СЕ. Это также позволит нам исследовать потенциальные проблемы использования команды IRAN для получения установившихся значений переменных составляющих. 

    Усилитель без эмиттерного конденсатора

    Обратимся к рис. 10.13, где приведена схема без СЕ. Входной файл для анализа: 

    Phase Relations in СЕ Amplifier

    VCC 4 0 12V

    R1 4 1 40k

    R2 1 0 5k

    RC 4 2 1k

    RE 3 0 100

    Rs 6 5 100

    RB 1 1A 0.01

    C1 5 1 15uF

    Q1 2 1A 3 BJT

    .MODEL BJT NPN (BF=80)

    vs 6 0 sin (0 10mV 5kHz)

    .TRAN 0.02ms 0.2ms

    .PROBE

    .END
     

    Проведите анализ и получите в Probe графики напряжений на коллекторе v(2), эмиттере v(3) и напряжения источника v(6). Обратите внимание, что входное напряжение и напряжение на эмиттере находятся в фазе, в то время как напряжение на коллекторе повернуто на 180°. Убедитесь, что значение максимума переменной составляющей v(2) равно 88,75 мВ, а максимальные значения для v(3) и v(6) составляют 9 мВ и 10 мВ соответственно. Таким образом, анализ переходных процессов был успешно использован для получения установившихся значений, и результаты были такими, какие мы ожидали бы из расчета с помощью стандартных методов. Сравните полученные вами графики с показанными на рис. 10.20.

    Рис. 10.20. Временные диаграммы напряжений в схеме на рис. 10.18

    Усилитель с эмиттерным конденсатором

    Однако обычно усилитель работает с конденсатором СЕ, подключенным параллельно RЕ. Давайте снова вставим во входной файл исключенную строку

    СЕ 3 0 10uF

    и заново выполним анализ. Получите в Probe только график напряжения на эмиттере, занимающий весь экран, обратите внимание, что синусоида является искаженной. Если получить график для нескольких периодов этого напряжения, то мы увидим, что прежде, чем режим устанавливается, колебание проходит фазу переходного процесса. В лаборатории обычный осциллограф показал бы форму колебаний правильно, так почему же Probe показывает иначе? Причина заключается в том, что мы используем анализ переходных процессов в схеме с реактивными элементами. Следовательно, мы должны быть внимательными и учитывать возможность появления похожих проблем в других задачах.

    Получите график v(2) и убедитесь, что v(2)=0,929 В (максимальное значение переменной составляющей) и что такое же значение для v(3) составляет 3,5 мВ. Убедитесь также, что напряжение на коллекторе немного искажено: на оси Y его значение равно 8,6345 В, максимум составляет 9,614 В и минимум достигается при значении 7,756 В (рис. 10.21).

    Рис. 10.21 Временные диаграммы напряжений в схеме на рис. 10.1 с блокирующим конденсатором


    Убедитесь, что при f=5 кГц конденсатор не является идеальным коротким замыканием. Вычислите полное сопротивление для параллельного соединения RE и СЕ. Оно равно Z=3,18∠88° Ом.

    В качестве упражнения получите графики токов через СЕ и тока через RЕ. Для сравнения можно построить и ток эмиттера. График тока эмиттера можно получить как –IE(Q1). Обратите внимание на фазовые соотношения между различными токами и между напряжением на эмиттере и входным напряжением. 

    Триггер на биполярных транзисторах

    Рис. 10.22. Триггер на биполярных транзисторах


    Триггер, использующий транзисторы BJT npn-типа, показан на рис. 10.22. Для обеспечения правильной работы в этом мультивибраторе с двумя устойчивыми состояниями один транзистор должен находиться в режиме глубокой отсечки, в то время как другой транзистор должен быть насыщен. Допустим, что в начальном состоянии транзистор Q1 заперт, а транзистор Q2 включен. Воспользуемся стандартными методами анализа:

    Этого обратного смещения достаточно, чтобы запереть Q1. Определим ток коллектора для другого транзистора, вычислив IRC2 и IR2:

    полагая, что V4=0. 

    Ток коллектора транзистора Q2 будет соответствовать разности:

    IC2IRC2IR2 = 5,35мА.

    При этом минимальный ток базы IВ2, необходимый для насыщения Q2, равен

    Ток базы можно найти как разность двух компонентов:

    приняв V5=0.

    Ток базы IВ2 транзистора Q2 равен:

    IB2 = IR1 IR4 = 0,58 мА,

    и имеет значение, намного превышающее минимум, требуемый для насыщения. 

    Так как схема симметричная, и мы предполагали, что изначально транзистор Q1 включен, а транзистор Q2 выключен, анализ приведет к аналогичным результатам, если начальное состояние транзисторов будет противоположным. 

    Анализ на PSpice

    Чтобы выполнить анализ на PSpice, примем, что транзистор Q1 заперт, как мы делали в стандартном анализе. Учтем это во входном файле, применив команду .NODESET. Входной файл при этом принимает вид:

    BJT Flip-flop (Q1 off)

    VCC 3 0 12V

    VBB 6 0 -12V

    RC1 3 2 2.2k

    RC2 3 4 2.2k

    R1 2 5 15k

    R2 4 1 15k

    R3 1 6 100k

    R4 5 6 100k

    Q1 2 1 0 QN

    Q2 4 5 0 QN

    .MODEL QN NPN(IS=1E-9 BF=30 BR=1 TF=0.2ns TR=5ns)

    .NODESET V(4)=0.15V; допустим, что Q2 включен (насыщен)

    .OP

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC1) I(RC2) I(R1) I(R2)

    .END

    Значение .NODESET для V(4)=0,15 В представляет собой начальное условие, которое используется при анализе на PSpice. Когда итеративный процесс решения закончится, это значение, вероятно, изменится.

    Проведите анализ на PSpice и убедитесь, что напряжения узлов и токи смещения близки к полученным при стандартном схемотехническом расчете. Отметим также, что приведенные в выходном файле под заголовком BIPOLAR-JUNCTION TRANSISTORS значения эксплуатационного режима напряжений, токов и b??!! близки к тем, которые ожидались. Результаты показаны на рис. 10.23.

    ВJТ Flip-flop (Q1 оff)

    VCC 3 0 12V

    VBB 6 0 -12V

    RC1 3 2 2.2k

    RC2 3 4 2.2k

    R1 2 5 15k

    R2 4 1 15K

    R3 1 6 100k

    R4 5 6 100k

    Q1 2 1 0 QN

    Q2 4 5 0 QN

    .MODEL QN NPN(IS=1E-9 BF=30 BR=1 TF=0.2ns TR=5ns)

    .NODESET V(4)=0.15V; guess for Q2 on (in saturation)

    .OP

    .opt nopage

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC1) I(RC2) I(R1) I(R2)

    .END

    **** BJT MODEL PARAMETERS

       QN

       NPN

    IS 1.000000E-09

    BF 30

    NF 1

    BR 1

    NR 1

    TF 200.000000E-12

    TR 5.000000E-09

    VCC       I(RC1)    I(RC2)    I(R1)     I(R2)

    1.200Е+01 6.742E-04 5.421E-03 6.742E-04 1.050E-04

    NODE VOLTAGE NODE  VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) -1.5012 ( 2)  10.5170 ( 3) 12.0000 ( 4) .0736

    ( 5) .4037   ( 6) -12.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -6.095E-03

    VBB  2.290Е-04

    TOTAL POWER DISSIPATION 7.59Е-02 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME     Q1       Q2

    MODEL    QN       QN

    IB      -1.05E-09 5.503-04

    IС       1.02E-09 5.32E-03

    VBE     -1.50E+00 4.04E-01

    VLC     -1.20E+01 3.30E-01

    VCE      1.05Е+01 7.36E-02

    BETADC  -9.78E-01 9.66E+00

    GM       0.00E+00 2.19E-01

    RPI      3.00E+13 1.29E+02

    RX       0.00E+00 0.00E+00

    RO       1.00E+12 7.40Е+01

    CBE      2.00E-22 4.65E-11

    CPC      5.00Е-21 6.76Е-11

    CJS      0.00E+00 0.00E+00

    BETAAC   0.00E+00 2.03E+01

    CBX/CBX2 0.00E+00 0.001+00

    FT/FT2   0.00E+00 3.00E+08

    Рис. 10.23. Выходной файл для схемы на рис. 10.22


    Интересно выполнить анализ с противоположными начальными условиями, установленными для Q1 и Q2, то есть используя начальное условие V(2)=0,15 В вместо V(4)=0,15 В. Результаты показывают, что роли двух транзисторов BJT изменяются, различные напряжения и токи принимают значения, полученные для другого прибора. Выходной файл приведен на рис. 10.24.

    ВJТ Flip-flop (Q1 on)

    VCC 3 0 12V

    VBB 6 0 -12V

    RC1 3 3 2.2k

    RC2 3 4 2.2k

    R1 2 5 15k

    R2 4 1 15k

    R3 1 6 100k

    R4 5 6 100k

    Q1 2 1 0 QN

    Q2 4 5 0 QN

    .MODEL QN NPN(IS=1E-9 BF=30 BR=1 TF=0.2ns TR=5ns)

    .NODESET V(2)=0.15V; guess for Q1 on (in saturation)

    .OP

    .opt nopage

    .DC VCC 12V 12V 12V

    .PRINT DC I(RC1) I(RC2) I(R1) I(R2)

    .END

    **** BJT MODEL PARAMETERS

       QN

       NPN

    IS 1.000000E-09

    BF 30

    NF 1

    BR 1

    NR 1

    TF 200.000000E-12

    TR 5.000000E-09

    VCC       I(RC1)    I(RC2)    I(R1)     I(R2)

    1.200E+01 5.421E-03 6.742Е-04 1.050E-04 6.742E-04

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) .4037   ( 2) .0736   ( 3) 12.0000 ( 4) 10.5170

    ( 5) -1.5012 ( 6) -12.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -6.095E-03

    VBB  2.290E-04

    TOTAL POWER DISSIPATION 7.59E-02 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME     Q1        Q2

    MODEL    QN        QN

    IB       5.50E-04 -1.05E-09

    IС       5.32E-03  1.02E-09

    VBE      4.04E-01 -1.50E+00

    VBC      3.30E-01 -1.20E+01

    VCE      7.36E-02  1.05E+01

    BETADC   9.66E+00 -9.78E-01

    GM       2.19Е-01  0.00E+00

    RPI      1.29E+02  3.00E+13

    RX       0.00E+00  0.00E+00

    RO       7.40E+01  1.00E+12

    СВЕ      4.65E-11  2.00E-22

    CBC      6.76E-11  5.00E-21

    CJS      0.00E+00  0.00E+00

    BETAAC   2.83E+01  0.00E+00

    CBX/CBX2 0.00E+00  0.00E+00

    FT/FT2   3.06E+08  0.00E+00

    Рис. 10.24. Выходной файл для схемы на рис. 10.22 с другим начальным состоянием

    Симметричный мультивибратор

    Симметричный мультивибратор с коллекторными связями представляет собой автогенератор. Эта схема может быть трудна для анализа на PSpice, поскольку при некоторых наборах параметров процесс итераций может не сходиться. На рис. 10.25 представлена симметричная схема, содержащая два транзистора BJT с коэффициентом усиления hFE=80. Мы можем вычислить период колебания по формуле

    Т = 0,6930(R1C1 + R2C2) = 1,386RC.

    Рис. 10.25. Мультивибратор с коллекторными связями


    Примем для параметров схемы соотношения R1=R2=R и С1=С2=С при использовании стандартных значений для резисторов и конденсаторов R=56 кОм и С=100 пФ. Для нашего примера это дает значения периода Т=7,762 мкс и частоты f=128,8 кГц. Входной файл:

    Astable Multivibrator

    VCC 5 0 5V

    RC1 5 1 1k

    RC2 5 2 1k

    R1 5 3 56k

    R2 5 4 56k

    C1 1 4 100pF

    C2 2 3 100pF

    Q1 1 3 0 QN

    Q2 2 4 0 QN

    .MODEL QN NPN (IS = 1E-12 BF = 80 BR=1 TF = 0.2ns TR=5ns)

    .NODESET V(1)=0 V(3)=0

    .OP

    .OPT nopage

    .PRINT DC 1(RC1) I(RC2) I(R1) I(R2)

    .TRAN 0.18us 18us

    .PROBE

    .END

    Заслуживает обсуждения команда .TRAN. Поскольку период, как известно, составляет немногим более 7 мкс, анализ должен проводиться на интервале до 20 мкс, чтобы дать колебаниям установиться. Когда использовалось время 20 мкс, итерации не сходились и графики были неверными. Попытки использовать другой шаг также были неудачны. Однако существуют некоторые комбинации, при которых получаются удовлетворительные результаты. Например, интервал 18 мкс при шаге 0,18 мкс дает хорошие результаты. Временная диаграмма для напряжения на коллекторе показана на рис. 10.26, для напряжения на базе — на рис. 10.27. При использовании курсора вы можете убедиться, что Т=7,865 мкс и, соответственно, f=127 кГц. Эти значения близки к значениям, полученным нами при расчете. Напряжения смещения для малосигнального режима и начальные значения для напряжений в переходном процессе показаны в выходном файле (рис. 10.28).

    Рис. 10.26. Напряжения на коллекторах транзисторов для схемы на рис. 10.25


    Рис. 10.27. Напряжения на базах транзисторов для схемы на рис. 10.25


    Astable Multivibrator

    VCC 5 0 5V

    RC1 5 1 1k

    RC2 5 2 1k

    R1 5 3 56k

    R2 5 4 56k

    C1 1 4 100pF

    C2 2 3 100pF

    Q1 1 3 0 QN

    Q2 2 4 0 QN

    .MODEL QN NPN(IS=1E-12 BF=80 BR=1 TF=0.2ns TR=5ns)

    .NODESET V(1)=0 V(3)=0

    .OP

    .opt nopage

    .PRINT DC I(RC1) I(RC2) I(R1) I(R2)

    .TRAN 0.18us 18us

    .PROBE

    .END

    **** BJT MODEL PARAMETERS

       QN

       NPN

    IS 1.000000E-12

    BF 80

    NF 1

    BR 1

    NR 1

    TF 200.000000E-12

    TR 5.000000E-09

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) .1452   ( 2) .1452   ( 3) .5770   ( 4) .5770

    ( 5) 5.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -9.868E-03

    TOTAL POWER DISSIPATION 4.93E-02 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME   Q1       Q2

    MODEL  QN       QN

    IB     7.90E-05 7.90E-05

    IС     4.85E-03 4.85E-03

    VBE    5.77E-01 5.77E-01

    VBC    4.32E-01 4.32E-01

    VCE    1.45E-01 1.45E-01

    BETADC 6.15E+01 6.15Е+01

    BETAAC 7.97E+01 7.97E+01

    **** INITIAL TRANSIENT SOLUTION TEMPERATURE = 27.000 DEG С

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) .1452   ( 2) .1452   ( 3) .5770   ( 4) .5770

    ( 5) 5.0000

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -9.868E-03

    TOTAL POWER DISSIPATION 4.93E-02 WATTS

    Рис. 10.28. Выходной файл с результатами анализа схемы на рис. 10.25

    Мультивибратор с эмиттерными связями на биполярных транзисторах

    На рис. 10.29 показан мультивибратор с эмиттерными связями, использующий стандартные компоненты. Его подробный анализ приведен в книге Millman, Taub, Pulse, Digital, and Switching Waveforms. При анализе принимается, что Q1 насыщается, a Q2 — нет. Мы устанавливаем начальное напряжение на коллекторе Q1 равным 25 В. Вы можете попробовать несколько различных значений напряжения в команде .nodeset и сравнить результаты. Теоретический анализ дает для периода колебаний значение Т=145,6 мкс.

    Рис. 10.29. Мультивибратор с эмиттерными связями


    В качестве упражнения создайте собственный входной файл для этой схемы. Убедитесь, что результаты, полученные в Probe, дают Т=151,4 мкс. Графики напряжений на коллекторе показаны на рис. 10.30. Обратите внимание, что по оси X выбран временной интервал от 0,6 до 1,0 мс. Выходной файл показан на рис. 10.31

    Рис. 10.30. Напряжения на коллекторах для схемы на рис. 10.29 


    **** 07/27/99 15:53:59 *********** Evaluation PSpice (Nov 1998) ***********

    Emitter-coupled multivibrator

    VCC 4 0 30V

    R1 4 2 10

    R2 2 0 20

    R3 2 3 1k

    RC1 4 3 1k

    RC2 4 8 200

    RE1 1 0 3.3k

    RE2 7 0 3.3k

    C1 2 0 0.1uF

    C2 1 7 0.1uF

    Q1 3 2 1 QN

    Q2 8 3 7 QN

    .MODEL QN NPN(IS=1E-12 BF=30 BR=1 TF=0.2ns TR=5ns)

    .NODESET V(3)=25V

    .OP

    .opt nopage

    .PRINT DC I(RC1) I(RC2) I(RE1) I(RE2)

    .TRAN 0.5us 1ms

    .PROBE

    .END

    **** BJT MODEL PARAMETERS

       QN

       NPN

    IS 1.000000E-12

    BF 30

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) 19.4310 ( 2) 20.0120 ( 3) 22.0520 ( 4) 30.0000

    ( 1) 21.4680 ( 8) 28.7410

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.013E+00

    TOTAL POWER DISSIPATION 3.04E+01 WATTS

    **** BIPOLAR JUNCTION TRANSISTORS

    NAME   Q1        Q2

    MODEL  QN        QN

    IB     1.90E-04  2.10E-04

    IС     5.70E-03  6.30E-03

    VBE    5.81E-01  5.84E-01

    VBC   -2.04E+00 -6.69E+00

    VCE    2.62E+00  7.27E+00

    BETADC 3.00E+01  3.00E+01

    BETAAC 3.00E+01  3.00E+01

    **** INITIAL TRANSIENT SOLUTION TEMPERATURE = 27.000 DEG С

    NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

    ( 1) 19.4310 ( 2) 20.0120 ( 3) 22.0520 ( 4) 30.0000

    ( 7) 21.4680 ( 8) 28.7410

    VOLTAGE SOURCE CURRENTS

    NAME CURRENT

    VCC -1.013E+00

    TOTAL POWER DISSIPATION 3.04Е+01 WATTS

    Рис. 10.31. Выходной файл с результатами анализа схемы на рис. 10.29

    Задачи

    10.1. Снимите входные и выходные характеристики библиотечного pnp- транзистора 2N3251 (hFE=180). Используйте схемы для снятия характеристик npn-транзисторов, представленные на рис. 10.1 и 10.3. Разработайте входной файл, позволяющий получить графики в Probe. Создайте метки для идентификации кривых.

    10.2. а) В схеме на рис. 10.32 hFE= 100. Найдите точку покоя, используя PSpice; затем сравните результаты с вашими вычислениями, приняв VBE=0,7 В. б) при анализе на PSpice примите, что hFE=50 и найдите точку покоя.

    Рис. 10.32


    10.3. Определите точку покоя для схемы, показанной на рис. 10.33, приняв, что hFE=60 и VBE=0,7 В. Проверьте ваши вычисления с помощью PSpice, воспользовавшись встроенной моделью транзистора.

    Рис. 10.33


    10.4. На рис. 10.34 представлена схема усилителя с ОЭ. Желательно, чтобы точка покоя позволяла реализовать максимальный размах колебаний тока коллектора при приемлемых искажениях. Транзистор имеет коэффициент усиления hFE=50.

    а) Найдите ток и напряжение коллектора в точке покоя, используя PSpice.

    б) Проведите PSpice/Probe анализ при синусоидальном входном напряжении vi и определите практический предел колебаний входного напряжения. Каковы колебания тока коллектора при этом условии?

    Рис. 10.34


    10.5. Усилитель с ОЭ и незашунтированным RE показан на рис. 10.35. Транзистор имеет коэффициент усиления hFE=100. Максимальное значение входного сигнала составляет 0,2 В. Используйте PSpice/Probe, чтобы получить временную диаграмму выходного напряжения и определить коэффициент усиления по напряжению.

    Рис. 10.35


    10.6. На рис. 10.36 показана схема с эмиттерными связями. Используйте анализ на PSpice, чтобы найти токи и напряжения смещения коллектора для Q1 и Q2. Оба транзистора имеют коэффициент усиления hFE=100.

    Рис. 10.36





     

    Главная | В избранное | Наш E-MAIL | Добавить материал | Нашёл ошибку | Наверх